ThinkScripter » A/D Ratio

Advance/Decline Box

ThinkScripter — Sun, 03 Jan 2010 18:48:57 +0000

Here’s a Sunday afternoon quickie for my loyal readers. While playing with some of the recently added new toys in thinkScript, I build this quick study that displays the Advance Decline Ratio or Advancing-Declining Issues in a little box at the upper left. You can select if you want the A/D Ratio or A-D Issues in the study properties panel. I set the coloring up such that the box is red if the value has worsened from the previous bar or green if it has improved. As with all indicators which pull the $ADVN and $DECN data, it will not work on TICK charts. Best of luck trading in the new year! – Eric

Advance Decline Box

# TS_AdvanceDeclineBox
# thinkscripter@gmail.com
# Last Update 12 MAY 2010

def A = close("$ADVN");
def D = close ("$DECN");
def ADL = A - D;
def ADR = if A > D then A / D else -D / A;
input mode = {default Ratio, Issues};
def modeSwitch = if mode == mode.Ratio then 1 else 0;

AddChartLabel(yes, concat(
if modeSwitch then ADR else ADL, concat(" ",
if modeSwitch then ":1  A/D RATIO" else " A/D LINE")),
if modeSwitch then if ADR > ADR[1] then color.green else color.red else if ADL > ADL[1] then color.green else color.red);

Advance/Decline Issues or Volume – Upper Study

ThinkScripter — Fri, 20 Feb 2009 02:58:00 +0000

In an ongoing effort to simplify my charts I have modified the Market Breadth indicator to be superimposed on the volume. You must have the “Overlapped Volume” style setting selected. You can display NYSE or NASDAQ advancing-declining issues or advancing-declining volume. There is a scaling factor to minimize the plot to suit your needs.

Advance/Decline Upper

# ADVANCE-DECLINE-UPPER
# http://thinkscripter.wordpress.com
# thinkscripter@gmail.com
# Last Update 19 Feb 2009

declare on_volume;
declare upper;

input display = {default  ADIssues,  ADVolume};
input market = {default NYSE, NASDAQ};
input scaleFactor = 1.0;

def maxVolume = highestAll(volume);

def advancing = if(market, close("$advn/q"), close("$advn"));
def declining =  if(market, close("$decn/q"), close("$decn"));
def advVolume = if(market, close("$uvol/q"), close("$uvol"));
def decVolume = if(market, close("$dvol/q"), close("$dvol"));

def maxADV = max(highestAll(advVolume), highestAll(decVolume));
def maxADI = max(highestAll(advancing), highestAll(declining));
def ratioV = maxVolume/maxADV;
def ratioI = maxVolume/maxADI;

plot Breadth;

switch (display) {
case ADIssues:
Breadth = if(advancing - declining > 0, advancing - declining, declining - advancing)*scaleFactor*ratioI;
case ADVolume:
Breadth = if(advVolume - decVolume > 0, advVolume - decVolume, decVolume - advVolume)*ScaleFactor*ratioV ;
}

Breadth.AssignValueColor(
if display == display.ADIssues then
if advancing - declining > 0 then color.dark_green else color.dark_red
else if advVolume - decVolume > 0 then color.dark_green else color.dark_red);

Breadth.SetPaintingStrategy(paintingStrategy.HISTOGRAM);
Breadth.SetLineWeight(5);

Market Breadth

ThinkScripter — Wed, 21 Jan 2009 22:43:06 +0000

This indicator will plot market breadth for the NYSE or NASDAQ in one of four ways:

1) Advancing/Declining Issues Ratio
2) Advancing-Declining Issues Total
3) Advancing/Declining Volume Ratio
4) Advancing-Declining Volume Total

Market Breadth

# MARKETBREADTH
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 21 Jan 2009

declare lower;

input display = {default ADIssuesRatio, ADIssues, ADVolumeRatio, ADVolume};
input market = {default NYSE, NASDAQ};

def advancing = if(market, close("$advn/q"), close("$advn"));
def declining =  if(market, close("$decn/q"), close("$decn"));
def advVolume = if(market, close("$uvol/q"), close("$uvol"));
def decVolume = if(market, close("$dvol/q"), close("$dvol"));

plot Breadth;

switch(display) {
  case ADIssuesRatio:
    Breadth = if(advancing > declining, (advancing / declining), (-declining / advancing));
  case ADIssues:
    Breadth = advancing - declining;
  case ADVolume:
    Breadth = advVolume - decVolume;
case ADVolumeRatio:
    Breadth = if( advVolume > decVolume, (advVolume / decVolume), (-decVolume / advVolume));
}

Breadth.AssignValueColor(if Breadth >= 0.0 then color.green else color.red);
Breadth.SetPaintingStrategy(paintingStrategy.HISTOGRAM);
Breadth.SetLineWeight(3);

plot ZeroLine = 0.0;
ZeroLine.SetDefaultColor(color.white);