Smoothed RSI Inverse Fisher Transform

ThinkScripter — Sun, 28 Nov 2010 16:28:45 +0000

Sylvain Vervoort’s Smoothed RSI Inverse Fisher Transform, as presented in his article in the October 2010 Stocks and Commodities Magazine, begins by smoothing the price curve with the “rainbow” weighted moving average. This smoothed price curve is used to calculate an RSI, which is then smoothed with the Vervoort zero-lag exponential moving average. The resulting curve is then transformed with an inverse Fisher filter.
Fisher suggests that a breakout above 12 indicates buying opportunities and a breakdown below 88 indicates selling opportunities. These opportunities should then be studied in the context of a slow stochastic and Vervoort’s ARSI indicator.

Smoothed RSI Inverse FT

# TS_SmoothedRSI_InverseFisherTransform
# By Sylvain Vervoort - Oct 2010 S&C Magazine
# thinkScript adaptation by
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 28 NOV 2010

declare lower;

input RSIper = 4;
input EMAper = 4;
def ma1 = wma(close, 2);
def ma2 = wma(ma1, 2);
def ma3 = wma(ma2, 2);
def ma4 = wma(ma3, 2);
def ma5 = wma(ma4, 2);
def ma6 = wma(ma5, 2);
def ma7 = wma(ma6, 2);
def ma8 = wma(ma7, 2);
def ma9 = wma(ma8, 2);
def ma10 = wma(ma9, 2);
def RainbW = (5 * ma1 + 4 * ma2 + 3 * ma3 + 2 * ma4 + ma5 + ma6 + ma7 + ma8 + ma9 + ma10) / 20;
def x = 0.1 * (RSIWilder(price = RainbW, length = RSIper) - 50);
def EMA1 = ExpAverage(x, EMAper);
def EMA2 = ExpAverage(EMA1, EMAper);
def Difference = EMA1 - EMA2;
def ZlEma = EMA1 + Difference;

plot invfish = ((exp(2 * ZlEma) - 1) / (exp(2 * ZlEma) + 1) + 1) * 50;
invfish.setDefaultColor(color.red);

plot zero = 0;
zero.setDefaultColor(color.gray);

plot oneHundred = 100;
oneHundred.setDefaultColor(color.gray);

Fisher Transform Signals

ThinkScripter — Sat, 07 Mar 2009 21:45:13 +0000

Here’s a reader request for an upper study that plots Fisher Transform signals on the price bars.

Fisher Transform Signals

# FisherTransformSignals
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 20 June 2010

input signalOffsetFactor = 0.20;
input length = 10;
input threshold = 2.0;

def signalOffset = AvgTrueRange(high,close,low,10)*signalOffsetFactor;

def maxHigh = Highest(high, length);
def minLow = Lowest(low, length);

rec value = if maxHigh - minLow == 0 then 0 else 0.66 * ((close - minLow) / (maxHigh - minLow) - 0.5) + 0.67 * value[1];

def truncValue = if value > 0.99 then 0.999 else if value < -0.99 then -0.999 else value;

rec FT = 0.5 * (log((1 + truncValue) / (1 - truncValue)) + FT[1]);

def trendDown = if FT < FT[1] and FT[1] > FT[2] and FT[1] >= threshold then 1 else 0;
def trendUp = if FT > FT[1] and FT[1] < FT[2] and FT[1] <= -threshold then 1 else 0;

def cSignal = if trendUp then low-signalOffset else if trendDown then high+signalOffset else double.nan;

plot signalHighlight = cSignal;
signalHighlight.AssignValueColor(if trendUp then color.green else color.red);
signalHighlight.setLineWeight(1);
signalHighlight.setStyle(curve.points);
signalHighlight.setpaintingStrategy(paintingStrategy.LINE_VS_TRIANGLES);

plot signal = cSignal;
signal.setDefaultColor(color.white);
signal.setLineWeight(4);
signal.setStyle(curve.points);
signal.setpaintingStrategy(paintingStrategy.LINE_VS_SQUARES);

#alert(trendup or trendDown, if trendUp then "Long" else "Short", Alert.bar, sound.bell);

ThinkScripter » Fisher Transform

Smoothed RSI Inverse Fisher Transform

Fisher Transform Signals