! ! ! IMPORTANT ! ! !
It goes without saying, but I’m going to say it up front here with emphasis: – You should not trade this system unless you fully understand the basic concepts. You must do your own due diligence. A trading system does not relieve you of your responsibility for the trades. Just because a system shows a historical profit on your chart does not mean it will continue to do so in the future. Over-optimization of the MACD parameters to make the current chart as profitable as possible is a likely path to future destruction and is referred to as “Curve-Fitting.”

MACD Trading System

MACD with Bollinger Bands

# TS_MACD_BB
# By Eric Purdy, ThinkScripter LLC
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 07 Feb 2011

declare lower;

input price = close;
input BBlength = 10;
input BBNum_Dev = 1.0;
input MACDfastLength = 12;
input MACDslowLength = 26;
input MACDLength = 5;

def MACD_Data = MACD(fastLength=MACDfastLength, slowLength=MACDslowLength, MACDLength = MACDLength);

plot MACD_Dots = MACD_Data;
plot MACD_Line= MACD_Data;

plot BB_Upper = BollingerBandsSMA(price = MACD_Line, length=BBlength, Num_Dev_Dn=-BBNum_Dev, Num_Dev_Up=BBNum_Dev).UpperBand;
plot BB_Lower = BollingerBandsSMA(price = MACD_Line, length=BBlength, Num_Dev_Dn=-BBNum_Dev, Num_Dev_Up=BBNum_Dev).Lowerband;
plot BB_Midline = BollingerBandsSMA(price = MACD_Line, length=BBlength, Num_Dev_Dn=-BBNum_Dev, Num_Dev_Up=BBNum_Dev).MidLine;

BB_Upper.SetDefaultColor(color.gray);
BB_Lower.SetDefaultColor(color.gray);
BB_MidLine.SetDefaultColor(color.gray);
BB_MidLine.setStyle(curve.SHORT_DASH);

MACD_Line.setDefaultColor(color.white);

MACD_Dots.setStyle(curve.POINTS);
MACD_Dots.setLineWeight(2);
MACD_Dots.assignValueColor(if MACD_Line>MACD_line[1] then color.green else color.red);

plot zero = 0;
zero.assignValueColor(if MACD_line<0 then color.red else color.green);
zero.setLineWeight(2);

1) The price data used is (H+L+C)/3 rather than the close. I find this makes a subtle improvement in the display of divergences.

2) You can plot a second long time frame MACD line on the same chart (hidden by default).

3) The histogram bars are colored based on the relationship to the previous bar vice the standard above/below zero line coloring.

4) The color of the main MACD line is white when the slope is positive and purple when negative.

MACD HLC/3

# MACDHLC
# http://thinkscripter.wordpress.com
# thinkscripter@gmail.com
# Last Update 17 Jan 2009

declare lower;

input ShortTimeFrameFastLength = 7;
input ShortTimeFrameSlowLength = 28;
input STFMACDLength = 7;
input LongTimeFrameFastLength = 28;
input LongTimeFrameSlowLength = 112;
input LTFMACDLength = 5;

def fastAvg = ExpAverage(data = hlc3, length = ShortTimeFrameFastLength);
def slowAvg = ExpAverage(data = hlc3, length = ShortTimeFrameSlowLength);

plot STFValue = fastAvg - slowAvg;
STFValue.setLineWeight(2);
DEF STFslope = (STFValue-STFValue[1]);
DEF STFslopeColor = if(STFslope > 0.0,9,0);
STFValue.AssignValueColor(getColor(STFSlopeColor));
 
plot STFAvg = ExpAverage(data = STFValue, length = STFMACDLength);
STFAvg.SetDefaultColor(GetColor(8));

def LfastAvg = ExpAverage(data = hlc3, length = LongTimeFrameFastLength);
def LslowAvg = ExpAverage(data = hlc3, length = LongTimeFrameSlowLength);
 
plot LTFValue = LfastAvg - LslowAvg;
LTFValue.setDefaultColor(color.green);
LTFValue.hide();

plot Diff = STFvalue - STFavg;
diff.AssignValueColor(if diff >= diff[1] then Color.UPTICK else Color.DOWNTICK);
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetDefaultColor(GetColor(5));
 
plot ZeroLine = 0;
ZeroLine.SetDefaultColor(GetColor(0));