Daily MA on Intraday Chart

# TS_DailyMA
# By Eric Purdy, ThinkScripter LLC
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 20 Feb 2011

input period = 50;
input displace = 0;
input display = {default linear, stairStep};

def MA = (fold i = 1 + displace to period + 1 + displace
with sum = 0 do sum + getValue(close(period="Day"),i,period+1))/period;
def newDay = if getDay() != getDay()[1] then 1 else 0;

plot DailyMovingAverage = if display==display.linear then if newDay then MA else double.nan else MA;
DailyMovingAverage.setDefaultColor(color.yellow);
DailyMovingAverage.setLineWeight(2);
DailyMovingAverage.enableApproximation();

Pivot Point Moving Average

# TS_PivotPointMovingAverage
# By Eric Purdy, ThinkScripter LLC
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 30 Jan 2011

input period = 3;
input displace = 0;

plot PivotPointMovingAverage = (fold i = 1 + displace
to period + 1 + displace
with sum = 0 do sum
+ getValue(hlc3(period="Day"),i,period+1))/period;

PivotPointMovingAverage.setDefaultColor(color.magenta);
PivotPointMovingAverage.setLineWeight(2);

SMA Spread

# TS_SMA_SPREAD
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 07 OCT 2010

declare lower;

input sma_length = 50;

plot SMA_Spread = (Close - Average(close, sma_length)) / Average(close,sma_length) * 100;
SMA_Spread.setDefaultColor(color.blue);

plot zero = 0;
zero.setDefaultColor(color.white);
zero.hideTitle();

plot overbought = absValue(stdevAll(SMA_Spread));
overbought.setDefaultColor(color.red);
overbought.setLineWeight(2);

plot oversold = -absValue(stdevAll(SMA_Spread));
oversold.setDefaultColor(color.red);
oversold.setLineWeight(2);

def spreadHigh = highestAll(AbsValue(SMA_Spread));

plot A = spreadHigh/5;
A.setDefaultColor(color.dark_gray);
A.setStyle(curve.SHORT_DASH);
A.hideTitle();

plot B = -spreadHigh/5;
B.setDefaultColor(color.dark_gray);
B.setStyle(curve.SHORT_DASH);
B.hideTitle();

plot C = spreadHigh*2/5;
C.setDefaultColor(color.dark_gray);
C.setStyle(curve.SHORT_DASH);
C.hideTitle();

plot D = -spreadHigh*2/5;
D.setDefaultColor(color.dark_gray);
D.setStyle(curve.SHORT_DASH);
D.hideTitle();

plot E = spreadHigh*3/5;
E.setDefaultColor(color.dark_gray);
E.setStyle(curve.SHORT_DASH);
E.hideTitle();

plot F = -spreadHigh*3/5;
F.setDefaultColor(color.dark_gray);
F.setStyle(curve.SHORT_DASH);
F.hideTitle();

plot G = spreadHigh*4/5;
G.setDefaultColor(color.dark_gray);
G.setStyle(curve.SHORT_DASH);
G.hideTitle();

plot H =  -spreadHigh*4/5;
H.setDefaultColor(color.dark_gray);
H.setStyle(curve.SHORT_DASH);
H.hideTitle();

plot I = spreadHigh;
I.setDefaultColor(color.dark_gray);
I.setStyle(curve.SHORT_DASH);
I.hideTitle();

plot J = -spreadHigh;
J.setDefaultColor(color.dark_gray);
J.setStyle(curve.SHORT_DASH);
J.hideTitle();

This very basic script plots a close approximation of the cycle point moving average. You enter in the required price reversal for a cycle turn, a moving average period, and it does the rest courtesy of the TOS zigZag function. I had coded this script some time ago and found nothing particularly compelling about it but decided to use it to illustrate the only new thinkScript feature I saw in the last build; namely the defineColor() command. In the past, when ever I needed to control the color of some study plot dynamically, I had to hard code in the colors in the associated assignValueColor() statement. As such, the custom coloring was only modifiable by altering the thinkScript itself. Using the new defineColor() command allows the scripter to code in value assignable colors but also allow an end user to change those colors should they desire. I expect to retrofit my earlier studies with this capability as time allows.

Break….Break….

Thanks to all for bearing with me this week. I know my response to your emails has been a bit slower than usual but I think I’ve gotten back to just about everyone at this point. It’s been a pretty busy week for myself and the family as we move back into our house after a four year absence in Annapolis. As such I haven’t really had as much time to devote to developmental stuff as I would like. I expect to be full steam ahead by early next week. 

Cycle Point Moving Average

# TS_CyclePointMovingAverage
# (c) 2009 http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 19 May 2009

declare fullrange;

input RequiredPointsForCycleReversal = 10;
input CycleMovingAveragePeriod = 7;

def ZZData = ZigZagSign("reversal amount" = RequiredPointsForCycleReversal);
def isHigh = if ZZData[1] < ZZData and ZZData > ZZData[-1] then 1 else 0;
def isLow = if ZZData[1] > ZZData and ZZData < ZZData[-1] then 1 else 0;
plot cyclePoint = if isHigh then high else if isLow then low else double.nan;
plot CPMA = Average(ZZData, CycleMovingAveragePeriod);

CPMA.DefineColor("Positive Slope", color.cyan);
CPMA.DefineColor("Negative Slope", color.magenta);
CPMA.AssignValueColor(if CPMA - CPMA[1] >= 0 then CPMA.color("Positive Slope") else CPMA.color("Negative Slope"));
CPMA.setLineWeight(3);

cyclePoint.SetStyle(curve.POINTS);
cyclePoint.SetDefaultColor(color.white);
cyclePoint.SetLineWeight(5);

Thanks to Reader Randy H. for suggesting this one. In his article “The Quest For Reliable Crossovers” (Stocks & Commodities Magazine, May 2008) author Sylvain Vervoort sets forth a trading method using the crosses of two unique moving averages. Specifically, he used a zero-lag triple exponential moving average of 1) the typical price (h+l+c)/3 and 2) the Heikin-Ashi close. He successfully backtested his method on 211 stocks and found using a 55 period average on daily charts was optimal.

Vervoort Crossover

# VervoortCrossover
# (c) 2009 http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 30 MAR 2009

input period = 55;
def price = (high+low+close)/3;

#-----Typical Price ZeroLag Triple Exponential Moving Average

def TMA1 = 3*expAverage(price,period)
-3*expAverage(expAverage(price,period),period)
+expAverage(expAverage(expAverage(price,period)
,period),period);

def TMA2 = 3*expAverage(TMA1,period)
-3*expAverage(expAverage(TMA1,period),period)
+expAverage(expAverage(expAverage(TMA1,period)
,period),period);

def difference = TMA1-TMA2;
plot TypicalPriceZeroLagTEMA = TMA1+difference;
TypicalPriceZeroLagTEMA.setDefaultColor(color.green);

#------Heikin-Ashi Close ZeroLag Triple Exponential Moving Average

rec haopen = CompoundValue(1,((open[1]+high[1]
+low[1]+close[1])/4 + haopen[1])/2, hl2);
def haclose = ((open+high+low+close)/4+haopen
+max(high,haopen)+min(low,haopen))/4;

def HATMA1 = 3*expAverage(haclose,period)
-3*expAverage(expAverage(haclose,period),period)
+expAverage(expAverage(expAverage(haclose,period)
,period),period);

def HATMA2 = 3 * ExpAverage(HATMA1, period)
- 3 * ExpAverage(ExpAverage(HATMA1, period), period)
+ ExpAverage(ExpAverage(ExpAverage(HATMA1, period)
, period), period);

def HAdifference = HATMA1 - HATMA2;

plot HeikinAshiZeroLagTEMA = HATMA1 + HAdifference;
HeikinAshiZeroLagTEMA.setDefaultColor(color.red);

def buySignal = if TypicalPriceZeroLagTEMA > HeikinAshiZeroLagTEMA and TypicalPriceZeroLagTEMA[1] <= HeikinAshiZeroLagTEMA[1] then 1 else 0;

def sellSignal = if TypicalPriceZeroLagTEMA < HeikinAshiZeroLagTEMA and TypicalPriceZeroLagTEMA[1] >= HeikinAshiZeroLagTEMA[1] then 1 else 0;

plot signal = if buySignal or sellSignal then TypicalPriceZeroLagTEMA else double.nan;
#signal.assignValueColor(if buySignal then color.green else color.red);
signal.setLineWeight(5);
signal.SetStyle(curve.points);

Variable Index Dynamic Moving Average

# VIDYA
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 15 MAR 2009

input sigmaperiod = 10;
input length = 20;

def sigmaConstant = 2/(sigmaperiod+1);
def absCMO = absValue(ChandeMomentumOscillator(length))/100;
rec cV = compoundValue(1, (sigmaConstant*absCMO*close)+(1-(sigmaConstant*absCMO))*cV[1],close);

plot VIDYA =cV;

Moving Average with Slope Based Color

# TS_MOVINGAVERAGE
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 15 MAR 2009

input displace = 0;
input length = 9;
input price = close;
input movingAverageType = {default Simple, Exponential, Weighted, Hull, Variable};

rec data;

switch (movingAverageType) {
case Simple:
    data = compoundValue(1, Average(price[-displace], length), price);
case Exponential:
    data = compoundValue(1, ExpAverage(price[-displace], length), price);
case Weighted:
    data = compoundValue(1, wma(price[-displace], length), price);
Case Hull:
    data = compoundValue(1, hullMovingAvg(price[-displace], length), price);
case variable:
    data = VariableMA(price=price, length=length);
}

plot ave = data;
ave.SetLineWeight(2);
ave.AssignValueColor(if ave > ave[1] then color.cyan else color.dark_red);
ave.HideBubble();