ThinkScripter » oscillator

DT Oscillator

ThinkScripter — Sun, 18 Oct 2009 03:21:52 +0000

Here’s a Saturday evening quickie. Lou dropped into the forum last week looking for a simple thinkScript conversion of the DT Oscillator code he had. It’s pretty basic but I thought I’d post it here in case you missed it in the forum. In essence it is just another version of the Stochastic RSI. I’ve been a bit quiet these days in the forum as I have spent a fair amount of time deep in the ThinkScripter laboratory cooking up some new goodies for you all. A careful examination of the price pane will reveal that the daily version of the Volume Profile is nearly complete. Stay tuned….

DT Oscillator

# TS_DTOscillator thinkScript translation by ThinkScripter
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 15 OCT 2009

declare lower;

input RSIPeriod = 13;
input StochasticPeriod=8;
input MAType = {default SMA,EMA};
input KPeriod = 5;
input DPeriod = 3;
input upper = 70;
input lower = 30;

def StoRSI= 100*(( RSIWilder( RSIPeriod) - lowest( RSIWilder( RSIPeriod ) , StochasticPeriod ) ) / ( (
highest( RSIWilder( RSIPeriod) , StochasticPeriod ) ) - lowest(RSIWilder( RSIPeriod ), StochasticPeriod ) )
);

def SK;
def SD;

Switch (MAType){
case SMA:
SK=average(StoRSI,KPeriod);
SD=average(SK,Dperiod);
case EMA:
SK=ExpAverage(StoRSI,KPeriod);
SD=ExpAverage(SK,DPeriod);
}

Plot DTOscSK = SK;
DTOscSK.setDefaultColor(color.blue);
plot DTOscSD = SD;
DTOscSD.setDefaultCOlor(color.gray);
DTOscSD.setStyle(curve.SHORT_DASH);
plot zero = 50;
zero.setDefaultColor(color.white);
plot UpperL = upper;
UpperL.setDefaultColor(color.red);
plot LowerL = lower;
lowerL.setDefaultColor(color.green);

3/10 Oscillator

ThinkScripter — Tue, 07 Apr 2009 00:26:55 +0000

Reader Steve H commissioned me to build this popular study used by Linda Bradford Raschke. The indicator itself is exceptionally simple. The fast line (red) is a 10 period simple moving average subtracted from a 3 period simple moving average. The slow line (cyan) is then a 16 period SMA of the slow line. The histogram is the delta between these two lines and therefore crosses the zero line when the fast and slow line cross. The histogram is hidden by default but can be revealed in the normal manner on the study properties pane.

3/10 Oscillator

# THREE TEN OSCILLATOR
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 06 APR 2009

declare lower;

input price = close;

def SMA3 = average(price, 3);
def SMA10 = average(price, 10);

def osc = SMA3-SMA10;
def ave = average(osc, 16);

plot deltaHistogram = osc-ave;
deltaHistogram.setPaintingStrategy(paintingStrategy.HISTOGRAM);
deltaHistogram.assignValueColor(if deltaHistogram > 0 then color.green else color.red);
deltaHistogram.hide();

plot osc310 = osc;
osc310.setDefaultColor(color.red);

plot ave16 = ave;
ave16.setDefaultColor(color.cyan);

plot zero = 0;
zero.setDefaultColor(color.white);

Heikin-Ashi Candlestick Oscillator

ThinkScripter — Wed, 01 Apr 2009 21:36:38 +0000

Here’s another one from the mind of Sylvain Vervoot. In “Trading With The Heikin-Ashi Candlestick Oscillator” (Stocks and Commodities, December 2008), Vervoot describes a methodolgy for creating a “visual tool to complement (Heikin-Ashi) candlesticks, helping you enter and exit trades, resulting in higher profits per trade.” In a nutshell, the Heikin-Ashi Candlestick Oscillator (HACO) uses the triple exponential moving average (TEMA) to filter out some of the whipsaws inherent in basic Heikin-Ashi candlesticks. There’s a fair bit more to it than that but you can explore the article on your own. The indicator itself is just a binary “Buy/Sell” signal as shown by the alternating red and green colors. I’ve circled the places in the traditional Heikin-Ashi chart where a trend change was indicated but the HACO correctly filtered out the signal. The HACO can be used on any symbol and timeframe. As with the Vervoot Crossover, the HACO can easily be turned into a strategy which is also pictured below. In this instance, a two day five minute chart of the ES was used resulting in a proft of $2612 on one contract. The up/down trend moving average periods were set to 27 within the HACO. Full results are here. UPDATE: The HACO strategies have been uploaded to “Door Number Three” of the Gold Donor area of the forum. (I’ll send out a donor update on Sunday as usual but if you can’t wait, just shoot me an email)

Heikin-Ashi Candlestick Oscillator

Polarized TRIN Oscillator

ThinkScripter — Thu, 26 Mar 2009 23:44:14 +0000

I’ve been messing with the TRIN as of late and crafted this polarized oscillator using the average value of the TRIN and TRINQ. The oscillator has been inverted so that a rising oscillator line is indicative of rising prices vice the way the actual TRIN works. I’d have to classify this one as experimental so feel free to hack away and post your modified version in the comments. I’ll be creating a user submissions page over the weekend and look forward to posting some of your best scripts!

Polarized TRIN Oscillator

# POLARIZEDTRINOSCILLATOR
# (c) 2009 http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 26 MAR 2009

declare lower;

input length = 9;
input EMA_period = 5;

def trin = close("$TRIN");
def trinq = close("$TRIN/Q");

def aveTrin = (trin+trinq)/2;

def fractal = sqrt(power(aveTrin-aveTrin[length],2)+100);
def incremental = sqrt(power(aveTrin-aveTrin[1],2)+1);
def sum = sum(incremental,length);

def resultant = if aveTrin-aveTrin[length] > 0 then round((fractal/sum)*100) else round(-(fractal/sum)*100);

def polarizedTrin = if resultant == 0 then 1 else resultant;
plot PTO = expAverage(-polarizedTrin, EMA_period);
PTO.setDefaultColor(color.yellow);

plot zeroline = 0.0;
zeroline.setDefaultColor(color.white);
plot plusLine =75;
plusLine.setDefaultColor(color.cyan);
plot minusLine = -75;
minusLine.setDefaultColor(color.cyan);