Pivot Point Moving Average

# TS_PivotPointMovingAverage
# By Eric Purdy, ThinkScripter LLC
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 30 Jan 2011

input period = 3;
input displace = 0;

plot PivotPointMovingAverage = (fold i = 1 + displace
to period + 1 + displace
with sum = 0 do sum
+ getValue(hlc3(period="Day"),i,period+1))/period;

PivotPointMovingAverage.setDefaultColor(color.magenta);
PivotPointMovingAverage.setLineWeight(2);

Auto-Hiding Fixed Pivots

# TS_FixedPivots
# http://thinkscripter.wordpress.com
# thinkscripter@gmail.com
# Last Update 20 APR 2009

input hide_if_percent = 1.0;
input pivot = 800.0;
input r_1 = 810.0;
input r_2 = 820.0;
input r_3 = 830.0;
input s_1 = 790.0;
input s_2 = 780.0;
input s_3 = 770.0;

def deltar1 = AbsValue(close - r_1);
def percentDeltar1 = (deltar1 / close) * 100.0;
plot r1 = if (percentDeltar1 < hide_if_percent, r_1, double.nan);
r1.SetDefaultColor(color.red);

def deltapp = AbsValue(close - pivot);
def percentDeltapp = (deltapp / close) * 100.0;
plot pp = if (percentDeltapp < hide_if_percent, pivot, double.nan);
pp.SetDefaultColor(color.white);

def deltar2 = AbsValue(close - r_2);
def percentDeltar2 = (deltar2 / close) * 100.0;
plot r2 = if (percentDeltar2 < hide_if_percent, r_2, double.nan);
r2.SetDefaultColor(color.red);

def deltar3 = AbsValue(close - r_3);
def percentDeltar3 = (deltar3 / close) * 100.0;
plot r3 = if (percentDeltar3 < hide_if_percent, r_3, double.nan);
r3.SetDefaultColor(color.red);

def deltas1 = AbsValue(close - s_1);
def percentDeltas1 = (deltas1 / close) * 100.0;
plot s1 = if (percentDeltas1 < hide_if_percent, s_1, double.nan);
s1.SetDefaultColor(color.green);

def deltas2 = AbsValue(close - s_2);
def percentDeltas2 = (deltas2 / close) * 100.0;
plot s2 = if (percentDeltas2 < hide_if_percent, s_2, double.nan);
s2.SetDefaultColor(color.green);

def deltas3 = AbsValue(close - s_3);
def percentDeltas3 = (deltas3 / close) * 100.0;
plot s3 = if (percentDeltas3 < hide_if_percent, s_3, double.nan);
s3.SetDefaultColor(color.green);

ThinkScripter Weekly/Monthly Pivots

# TS_Pivots
# (c) 2009 http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 20 APR 2009

input timeFrame = {default WEEK, MONTH};
input showOnlyToday = no;

def H = high(period = timeFrame)[1];
def L = low(period = timeFrame)[1];
def C = close(period = timeFrame)[1];

def calc_PP = (H + L + C) / 3;
def calc_R1 =  (2 * calc_PP) - L;
def calc_R2 = calc_PP + H - L;
def calc_R3 = H + 2 * (calc_PP - L);

def calc_S1 = (2 * calc_PP) - H;
def calc_S2 = calc_PP - H + L;
def calc_S3 = L - 2 * (H - calc_PP);

plot R3;
plot R2;
plot R1;
plot PP;
plot S1;
plot S2;
plot S3;

if (showOnlyToday and !IsNaN(close(period = timeFrame)[-1])) or
(getAggregationPeriod() > if timeframe == timeframe.WEEK then AggregationPeriod.WEEK else AggregationPeriod.MONTH)

then {
    R1 = Double.NaN;
    R2 = Double.NaN;
    R3 = Double.NaN;
    PP = Double.NaN;
    S1 = Double.NaN;
    S2 = Double.NaN;
    S3 = Double.NaN;
}
else {
    R1 = calc_R1;
    R2 = calc_R2;
    R3 = calc_R3;
    PP = calc_PP;
    S1 = calc_S1;
    S2 = calc_S2;
    S3 = calc_S3;
}

PP.SetDefaultColor(color.white);
R1.SetDefaultColor(color.red);
R2.SetDefaultColor(color.red);
R3.SetDefaultColor(color.red);
S1.SetDefaultColor(color.green);
S2.SetDefaultColor(color.green);
S3.SetDefaultColor(color.green);

PP.SetStyle(Curve.POINTS);
R1.SetStyle(Curve.POINTS);
R2.SetStyle(Curve.POINTS);
R3.SetStyle(Curve.POINTS);
S1.SetStyle(Curve.POINTS);
S2.SetStyle(Curve.POINTS);
S3.SetStyle(Curve.POINTS);

Also pictured are the ThinkScripter Multi-Stops using a fibonacci stop of the standard settings, as well as the Better Volume indicator from Emini-Watch. I simply ported his code over for use in thinkScript.

ThinkScripter RTH MultiPivots

Four Types of Pivots

1) yesterday’s high + (yesterday’s high-two day’s ago high)
2) yesterday’s low + (yesterday’s low-two day’s ago low)

Previous Day's Regular Hours H/L/C

# PREVDAYHLC
# (c) 2009 http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 08 Mar 2009

input showOnlyToday = YES;
input Market_Open_Time = 0930;
input Market_Close_Time = 1600;

def day = getDay();
def lastDay = getLastDay();
def isToday = if(day == lastDay, 1, 0);
def shouldPlot = if(showOnlyToday and isToday, 1, if(!showOnlyToday, 1, 0));

def pastOpen = if((secondsTillTime(Market_Open_Time) > 0), 0, 1);
def pastClose = if((secondsTillTime(Market_Close_Time) > 0), 0, 1);
def marketOpen = if(pastOpen and !pastClose, 1, 0);
def firstBar = if (day[1] != day, 1, 0);

def closingBell = if secondsTillTime(Market_Close_Time)[1] > 0 and
secondsTillTime(Market_Close_Time)<=0 or
(secondsTillTime(Market_Close_Time)[1]<secondsTillTime(Market_Close_Time)
and secondsTillTime(Market_Close_Time)[1]>0)  then 1 else 0;

rec regHoursHigh = if(high > regHoursHigh[1] and marketOpen, high,
if(marketOpen and !firstBar, regHoursHigh[1], high));
rec regHoursLow = if(low < regHoursLow[1] and marketOpen, low,
if(marketOpen and regHoursLow[1] > 0 and !firstBar, regHoursLow[1], low));

rec runningClose = compoundValue(1, if closingbell then close[1] else runningClose[1], close);
rec prevClose = compoundValue(1, if closingBell  then runningClose else prevClose[1], close);
rec prevHigh = compoundValue(1, if closingBell then regHoursHigh[1] else prevHigh[1], high);
rec prevLow = compoundValue(1, if closingBell then regHourslow[1] else prevlow[1], low);
rec prevHigh2 = compoundValue(1, if closingBell then prevHigh[1] else prevHigh2[1], high);
rec prevLow2 = compoundValue(1, if closingBell then prevLow[1] else prevlow2[1], low);

plot pc = if shouldPlot then prevClose else double.nan;
pc.SetStyle(curve.SHORT_DASH);
pc.setDefaultColor(color.white);

plot pl = if shouldPlot then prevLow else double.nan;
pl.SetDefaultColor(color.dark_red);
plot ph = if shouldPlot then prevHigh else double.nan;
ph.SetDefaultColor(color.dark_green);

plot pl2 = if shouldPlot then pl+(pl-prevLow2) else double.nan;
pl2.SetDefaultColor(color.darK_red);
pl2.SetStyle(curve.LONG_DASH);
plot ph2 =if shouldPlot then ph+(ph-prevHigh2) else double.nan;
ph2.SetStyle(curve.LONG_DASH);
ph2.SetDefaultColor(color.dark_green);

The formulas for the high and low pivot range are as follows:

The Pivot= (3day High + 3day Low + Close)/3
The Midpoint= (3day High + 3 day Low)/2
Pivot Range= Absolute Value (Pivot – Midpoint)
Pivot High= Pivot + Range
Pivot Low= Pivot – Range

Three Day Pivot Range

# THREEDAYPIVOTRANGE
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 22 Feb 2009

input timeFrame = {default DAY};
input showOnlyToday = no;

def day = getDay();
def lastDay = getLastDay();
def isToday = if(day >= lastDay, 1, 0);
def shouldPlot = if(showOnlyToday and isToday, 1, if(!showOnlyToday, 1, 0));

def HA = high(period = timeFrame)[1];
def HB = high(period = timeFrame)[2];
def HC = high(period = timeFrame)[3];
def LA = low(period = timeFrame)[1];
def LB = low(period = timeFrame)[2];
def LC = low(period = timeFrame)[3];
def C = close(period = timeFrame)[1];

def H3 = Max(Max(HA, HB), HC);
def L3 = Min(Min(LA, LB), LC);

def calc_PP = (H3 + L3 + C) / 3;
def calc_MP = (H3 + L3) / 2;
def calc_PR = AbsValue(calc_PP - calc_mp);
def calc_PH = Calc_PP + calc_PR;
def calc_PL = Calc_PP - calc_PR;

plot PH =if (shouldPlot , calc_PH, double.nan);
plot PL = if (shouldPlot , calc_PL, double.nan);

PH.setStyle(curve.POINTS);
PL.setStyle(curve.POINTS);

PH.SetDefaultColor(color.cyan);
PL.SetDefaultColor(color.yellow);

PH.SetStyle(Curve.POINTS);
PL.SetStyle(Curve.POINTS);