Smoothed RSI Inverse FT

# TS_SmoothedRSI_InverseFisherTransform
# By Sylvain Vervoort - Oct 2010 S&C Magazine
# thinkScript adaptation by
# http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 28 NOV 2010

declare lower;

input RSIper = 4;
input EMAper = 4;
def ma1 = wma(close, 2);
def ma2 = wma(ma1, 2);
def ma3 = wma(ma2, 2);
def ma4 = wma(ma3, 2);
def ma5 = wma(ma4, 2);
def ma6 = wma(ma5, 2);
def ma7 = wma(ma6, 2);
def ma8 = wma(ma7, 2);
def ma9 = wma(ma8, 2);
def ma10 = wma(ma9, 2);
def RainbW = (5 * ma1 + 4 * ma2 + 3 * ma3 + 2 * ma4 + ma5 + ma6 + ma7 + ma8 + ma9 + ma10) / 20;
def x = 0.1 * (RSIWilder(price = RainbW, length = RSIper) - 50);
def EMA1 = ExpAverage(x, EMAper);
def EMA2 = ExpAverage(EMA1, EMAper);
def Difference = EMA1 - EMA2;
def ZlEma = EMA1 + Difference;

plot invfish = ((exp(2 * ZlEma) - 1) / (exp(2 * ZlEma) + 1) + 1) * 50;
invfish.setDefaultColor(color.red);

plot zero = 0;
zero.setDefaultColor(color.gray);

plot oneHundred = 100;
oneHundred.setDefaultColor(color.gray);

Short Term Volume and Price Oscillator

# TS_ShortTermVolumeAndPriceOscillator
# (c) 2009 http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 20 SEP 2009

declare lower;

input period = 8;
input cutoff = 1.0;

input devH = 1.5; #Standard Deviation High
input devL = 1.3; #Standard Deviation Low
input stdevper = 100; #Standard Deviation Period

rec haopen = compoundValue(1, ((open[1] + high[1] + low[1] + close[1]) / 4 + haopen[1]) / 2, hl2);
def haclose = ((open + high + low + close) / 4 + haopen + Max(high, haopen) + Min(low, haopen)) / 4;

def hac = 3 * ExpAverage(haclose, period / 1.6)
- 3 * ExpAverage(ExpAverage(haclose, period / 1.6), period / 1.6)
+ ExpAverage(ExpAverage(ExpAverage(haclose, period / 1.6), period / 1.6), period / 1.6);

def vave = Average(volume, period * 5)[1];
def vmax = vave * 2;
def vc = if(volume < vmax, volume, vmax);

def vtrendi = inertia(volume,period);
def vtrend =vtrendi-vtrendi[1];

def vtr = 3 * ExpAverage(vtrend, period)
- 3 * ExpAverage(ExpAverage(vtrend, period), period)
+ ExpAverage(ExpAverage(ExpAverage(vtrend, period), period), period);

def calc1 = If haC > (haC[1]*(1+cutoff/1000)) and (vtr >=
vtr[1] and vtr[1] > vtr[2]) then vc else If haC < (haC[1]*(1-cutoff/1000)) and (vtr >=
vtr[1] and vtr[1] > vtr[2]) then -vc else 0;
def SVAPOBase = Sum(calc1,period)/(vave+1);

plot SVAPO = 3 * ExpAverage(SVAPOBase, period)
- 3 * ExpAverage(ExpAverage(SVAPOBase, period), period)
+ ExpAverage(ExpAverage(ExpAverage(SVAPOBase, period), period), period);
SVAPO.setDefaultColor(color.cyan);

plot upperSDLine = devH*Stdev(SVAPO,stdevper);
upperSDLine.setDefaultColor(color.red);
upperSDLine.setStyle(curve.SHORT_DASH);
plot lowerSDLine = -devL*Stdev(SVAPO,stdevper);
lowerSDLine.setDefaultColor(color.green);
lowerSDLine.setStyle(curve.SHORT_DASH);
plot zero = 0;
zero.setDefaultColor(color.white);

LONG_ENTRY; LONG_EXIT; SHORT_ENTRY; SHORT_EXIT

Since you can’t plot anything from a strategy, all plot statements for variables that will be part of the strategy logic should be converted to def statements and their formatting commands removed. Other non-essential plot statements and associated formatting can be removed entirely. Your entire goal when creating a strategy is to define a binary condition that will trigger a trade. In this particular case we are looking for a moving average cross. I had already coded that into the study for use with the signal dots:

def buySignal = if TypicalPriceZeroLagTEMA > HeikinAshiZeroLagTEMA and TypicalPriceZeroLagTEMA[1] <= HeikinAshiZeroLagTEMA[1] then 1 else 0;

With this condition we can now add the other essential piece of code for strategies – the addOrder(condition,price) command:

addOrder(buySignal,open[-1]);

Here you see the binary condition buySignal entered as the trigger argument and the price is the next bar’s open, hence the [-1] indexing.

Strategies only work in pairs. You can have a Long Entry and Long Exit pair or a Long Entry and Short Entry pair etc. In this case I used a daily chart with six months of data to run the backtest. With proper money and stop management to minimize drawdowns this looks to be a viable strategy. Profit was $7400 on a single ES contract over the preceding six month period. Full results here.

Vervoort Crossover Strategy Analysis

The Long Entry Code:

declare LONG_ENTRY;

input period = 55;
def price = (high+low+close)/3;

def TMA1 = 3 * ExpAverage(price, period)
- 3 * ExpAverage(ExpAverage(price, period), period)
+ ExpAverage(ExpAverage(ExpAverage(price, period), period), period);

def TMA2 = 3 * ExpAverage(TMA1, period)
- 3 * ExpAverage(ExpAverage(TMA1, period), period)
+ ExpAverage(ExpAverage(ExpAverage(TMA1, period), period), period);

def difference = TMA1 - TMA2;
def TypicalPriceZeroLagTEMA = TMA1 + difference;

rec haopen = compoundValue(1, ((open[1] + high[1] + low[1] + close[1]) / 4
+ haopen[1]) / 2, hl2);
def haclose = ((open + high + low + close) / 4 + haopen + Max(high, haopen)
+ Min(low, haopen)) / 4;

def HATMA1 = 3 * ExpAverage(haclose, period)
- 3 * ExpAverage(ExpAverage(haclose, period), period)
+ ExpAverage(ExpAverage(ExpAverage(haclose, period), period), period);

def HATMA2 = 3 * ExpAverage(HATMA1, period)
- 3 * ExpAverage(ExpAverage(HATMA1, period), period)
+ ExpAverage(ExpAverage(ExpAverage(HATMA1, period), period), period);

def HAdifference = HATMA1 - HATMA2;
def HeikinAshiZeroLagTEMA = HATMA1 + HAdifference;

def buySignal = if TypicalPriceZeroLagTEMA > HeikinAshiZeroLagTEMA
and TypicalPriceZeroLagTEMA[1] <= HeikinAshiZeroLagTEMA[1] then 1 else 0;

addOrder(buySignal,open[-1]);
setColor(color.green);

The Short Entry Code:

declare SHORT_ENTRY;

input period = 55;
def price = (high+low+close)/3;

def TMA1 = 3 * ExpAverage(price, period)
- 3 * ExpAverage(ExpAverage(price, period), period)
+ ExpAverage(ExpAverage(ExpAverage(price, period), period), period);

def TMA2 = 3 * ExpAverage(TMA1, period)
- 3 * ExpAverage(ExpAverage(TMA1, period), period)
+ ExpAverage(ExpAverage(ExpAverage(TMA1, period), period), period);

def difference = TMA1 - TMA2;
def TypicalPriceZeroLagTEMA = TMA1 + difference;

rec haopen = compoundValue(1, ((open[1] + high[1] + low[1] + close[1]) / 4
+ haopen[1]) / 2, hl2);
def haclose = ((open + high + low + close) / 4 + haopen + Max(high, haopen)
+ Min(low, haopen)) / 4;

def HATMA1 = 3 * ExpAverage(haclose, period)
- 3 * ExpAverage(ExpAverage(haclose, period), period)
+ ExpAverage(ExpAverage(ExpAverage(haclose, period), period), period);

def HATMA2 = 3 * ExpAverage(HATMA1, period)
- 3 * ExpAverage(ExpAverage(HATMA1, period), period)
+ ExpAverage(ExpAverage(ExpAverage(HATMA1, period), period), period);

def HAdifference = HATMA1 - HATMA2;
def HeikinAshiZeroLagTEMA = HATMA1 + HAdifference;

def sellSignal = if TypicalPriceZeroLagTEMA < HeikinAshiZeroLagTEMA
and TypicalPriceZeroLagTEMA[1] >= HeikinAshiZeroLagTEMA[1] then 1 else 0;

addOrder(sellSignal, open[-1]);
setColor(color.red);

Thanks to Reader Randy H. for suggesting this one. In his article “The Quest For Reliable Crossovers” (Stocks & Commodities Magazine, May 2008) author Sylvain Vervoort sets forth a trading method using the crosses of two unique moving averages. Specifically, he used a zero-lag triple exponential moving average of 1) the typical price (h+l+c)/3 and 2) the Heikin-Ashi close. He successfully backtested his method on 211 stocks and found using a 55 period average on daily charts was optimal.

Vervoort Crossover

# VervoortCrossover
# (c) 2009 http://www.thinkscripter.com
# thinkscripter@gmail.com
# Last Update 30 MAR 2009

input period = 55;
def price = (high+low+close)/3;

#-----Typical Price ZeroLag Triple Exponential Moving Average

def TMA1 = 3*expAverage(price,period)
-3*expAverage(expAverage(price,period),period)
+expAverage(expAverage(expAverage(price,period)
,period),period);

def TMA2 = 3*expAverage(TMA1,period)
-3*expAverage(expAverage(TMA1,period),period)
+expAverage(expAverage(expAverage(TMA1,period)
,period),period);

def difference = TMA1-TMA2;
plot TypicalPriceZeroLagTEMA = TMA1+difference;
TypicalPriceZeroLagTEMA.setDefaultColor(color.green);

#------Heikin-Ashi Close ZeroLag Triple Exponential Moving Average

rec haopen = CompoundValue(1,((open[1]+high[1]
+low[1]+close[1])/4 + haopen[1])/2, hl2);
def haclose = ((open+high+low+close)/4+haopen
+max(high,haopen)+min(low,haopen))/4;

def HATMA1 = 3*expAverage(haclose,period)
-3*expAverage(expAverage(haclose,period),period)
+expAverage(expAverage(expAverage(haclose,period)
,period),period);

def HATMA2 = 3 * ExpAverage(HATMA1, period)
- 3 * ExpAverage(ExpAverage(HATMA1, period), period)
+ ExpAverage(ExpAverage(ExpAverage(HATMA1, period)
, period), period);

def HAdifference = HATMA1 - HATMA2;

plot HeikinAshiZeroLagTEMA = HATMA1 + HAdifference;
HeikinAshiZeroLagTEMA.setDefaultColor(color.red);

def buySignal = if TypicalPriceZeroLagTEMA > HeikinAshiZeroLagTEMA and TypicalPriceZeroLagTEMA[1] <= HeikinAshiZeroLagTEMA[1] then 1 else 0;

def sellSignal = if TypicalPriceZeroLagTEMA < HeikinAshiZeroLagTEMA and TypicalPriceZeroLagTEMA[1] >= HeikinAshiZeroLagTEMA[1] then 1 else 0;

plot signal = if buySignal or sellSignal then TypicalPriceZeroLagTEMA else double.nan;
#signal.assignValueColor(if buySignal then color.green else color.red);
signal.setLineWeight(5);
signal.SetStyle(curve.points);